#!/usr/bin/awk -f
# Copyright 2001 Blossom Associates West
# All rights reserved.

# The first file is an HTML template with a table in it.
# Subsequent files contain the data. Typically TSV.
# The table can have lines like "<td>%s</td>" in it
# which will be filled in with fields in the TSV.
# The "" lines of the form above must be enclosed in tr tagged lines.
# e.g.  <tr>
#       <td align="right">%d:</td>
#       <td>%s</td>
#       </tr>
# Note that each td tag must be on a separate line.
# There must be only one such stanza in the template.

BEGIN {
  FALSE = 0;
  TRUE = ! FALSE;
  startTag = /< *[Bb][Oo][Dd][Yy]/;
  endTag = />/;
  printing = FALSE;
  tempSize = 0;
  DFLTFMT = "<td>%s</td>";
}

1 == FNR && 1 < NR {
  inData = TRUE;
}

inData {
  print rowHeader;
  for ( i = 1; i <= NF; i++ ) {
    if ( i <= tempSize ) {
      fmt = templ[i];
    }
    else {
      fmt = DFLTFMT;
    }
    printf( fmt, $i );
  }
  print rowTrailer;
  next;
}

/<td.*>%[-sd1-9].*<\/td/ && length( rowTrailer ) < 1 {
  tempSize++;
  templ[ tempSize ] = $0;
  next;
}

/<\/tr/ && 0 < tempSize {
  rowTrailer = $0;
}

0 < length( rowHeader ) {
  if ( tempSize < 1 ) {
    print rowHeader;
    rowHeader = "";
  }
}

/<tr/ {
  rowHeader = $0;
  next;
}

# Print the template verbatim before substitution lines.
tempSize < 1 {
  if ( "" != rowHeader ) {
    rowHeader = "";
  }
  print;
}

# accumulate template lines after substitutions.
# BUG if there are non substitution lines amont the substitution lines.
0 < tempSize {
  tail = tail ORS $0;
}

# Print the accumulated lines of the template after the substitution lines.
END {
  print tail;
}